ESP32-S3 Matrix RGB WS2812B Udviklingsboard

Specifikationer af ESP32-S3 Matrix RGB WS2812B Udviklingsboard

ESP32-S3 Matrix RGB WS2812B Udviklingsboard er en kompakt og kraftfuld Udviklingsboard. Denn er designet til at opfylde behovene hos både professionelle udviklere og hobbyister. Med en række avancerede funktioner er denne Udviklingsboard ideel til en bred vifte af applikationer, fra IoT-projekter til interaktive design. ESP32-S3 Matrix udstyret med en 8×8 RGB LED-matrix. Denne matrix gør det muligt at skabe imponerende lyseffekter og dynamiske visninger direkte fra Udviklingsboard. Hvilket gør den perfekt til kreative projekter og interaktive designløsninger.

Tekniske detaljer for ESP32-S3 Matrix Udviklingsboard

• Processor: Xtensa 32-bit LX7 dual-core processor med en hovedfrekvens på op til 240MHz
• SRAM: 512KB
• RAM: 384KB
• PSRAM: 2MB
• Flash: 4MB
• Wi-Fi: 2,4GHz Wi-Fi (802.11 b/g/n), understøtter 40MHz båndbredde
• Bluetooth: Bluetooth 5.0 (LE) og Bluetooth Mesh
• LED Matrix: 8×8 RGB LED-matrix

Sensor:
Type: QST QMI8658C holdningssensor
Funktion: Præcis bevægelsessporing og holdningsdetektion
GPIO Pins: 17
USB: USB Type-C, som eliminerer bekymringer om korrekt tilslutning

Installere Arduino IDE Software

Før du kan starte din programmering skal Arduino’s IDE software hentes. Dette program bruges til at programmere din arduino.
Download fra dette link: Download

Installere ESP package (Arduino IDE)

Åben Arduino IDE (Download her)
Klik “Fil/Egenskaber”
Indtast dette link i feltet “Additionel Board Manager URL’s”
Link “https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json“
Klik OK
Åben “Værktøj/Board/Boards manager” (Lad programmet opdatere)
Find “ESP32” og installere
Klik derefter “Værktøj/Board” og find (ESP32C6 Dev Module)
Du er nu klar til at sende en kode

Installere Adafruit NeoPixel Library

• Download library (Download)
• Åben Arduino IDE software og klik på “Sketch/Include library”
• Klik nu på “Add Zip. library” og find Zip filen du lige har downloaded.
• Luk, og åben Arduino IDE programmet. (Genstart programmet)
• Nu er library installeret.
• Library kan også downloades direkte i Arduino IDE find den her: “Sketch/Include library/Manage library/Adafruit NeoPixel – by Adafruit”

Installere SensorLib-master Library

• Download library (Download)
• Åben Arduino IDE software og klik på “Sketch/Include library”
• Klik nu på “Add Zip. library” og find Zip filen du lige har downloaded.
• Luk, og åben Arduino IDE programmet. (Genstart programmet)
• Nu er library installeret.
• Library kan også downloades direkte i Arduino IDE find den her: “Sketch/Include library/Manage library/SensorLib – by Lewis He”

Eksempel

Her præsenteres et hurtigt eksempel, der illustrerer, hvordan farverne dynamisk skifter mellem forskellige nuancer og skaber et levende farvespil. Dette skift tilfører designet en visuel dybde og kompleksitet, som kan være med til at fremhæve vigtige elementer og skabe en engagerende visuel oplevelse.

https://ardustore.dk/wp-content/uploads/2024/08/ESP32-S3-Matrix-RGB-WS2812B-Udviklingsboard-Produket.webp

Kode: (Programmering)

// A basic everyday NeoPixel strip test program.

// NEOPIXEL BEST PRACTICES for most reliable operation:
// - Add 1000 uF CAPACITOR between NeoPixel strip's + and - connections.
// - MINIMIZE WIRING LENGTH between microcontroller board and first pixel.
// - NeoPixel strip's DATA-IN should pass through a 300-500 OHM RESISTOR.
// - AVOID connecting NeoPixels on a LIVE CIRCUIT. If you must, ALWAYS
// connect GROUND (-) first, then +, then data.
// - When using a 3.3V microcontroller with a 5V-powered NeoPixel strip,
// a LOGIC-LEVEL CONVERTER on the data line is STRONGLY RECOMMENDED.
// (Skipping these may work OK on your workbench but can fail in the field)

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
#include <avr/power.h> // Required for 16 MHz Adafruit Trinket
#endif

// Which pin on the Arduino is connected to the NeoPixels?
// On a Trinket or Gemma we suggest changing this to 1:
#define LED_PIN 14

// How many NeoPixels are attached to the Arduino?
#define LED_COUNT 64

// Declare our NeoPixel strip object:
Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);
// Argument 1 = Number of pixels in NeoPixel strip
// Argument 2 = Arduino pin number (most are valid)
// Argument 3 = Pixel type flags, add together as needed:
// NEO_KHZ800 800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
// NEO_KHZ400 400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
// NEO_GRB Pixels are wired for GRB bitstream (most NeoPixel products)
// NEO_RGB Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
// NEO_RGBW Pixels are wired for RGBW bitstream (NeoPixel RGBW products)


// setup() function -- runs once at startup --------------------------------

void setup() {
// These lines are specifically to support the Adafruit Trinket 5V 16 MHz.
// Any other board, you can remove this part (but no harm leaving it):
#if defined(__AVR_ATtiny85__) && (F_CPU == 16000000)
clock_prescale_set(clock_div_1);
#endif
// END of Trinket-specific code.

strip.begin(); // INITIALIZE NeoPixel strip object (REQUIRED)
strip.show(); // Turn OFF all pixels ASAP
strip.setBrightness(50); // Set BRIGHTNESS to about 1/5 (max = 255)
}


// loop() function -- runs repeatedly as long as board is on ---------------

void loop() {
// Fill along the length of the strip in various colors...
colorWipe(strip.Color(255, 0, 0), 50); // Red
colorWipe(strip.Color( 0, 255, 0), 50); // Green
colorWipe(strip.Color( 0, 0, 255), 50); // Blue

// Do a theater marquee effect in various colors...
theaterChase(strip.Color(127, 127, 127), 50); // White, half brightness
theaterChase(strip.Color(127, 0, 0), 50); // Red, half brightness
theaterChase(strip.Color( 0, 0, 127), 50); // Blue, half brightness

rainbow(10); // Flowing rainbow cycle along the whole strip
theaterChaseRainbow(50); // Rainbow-enhanced theaterChase variant
}


// Some functions of our own for creating animated effects -----------------

// Fill strip pixels one after another with a color. Strip is NOT cleared
// first; anything there will be covered pixel by pixel. Pass in color
// (as a single 'packed' 32-bit value, which you can get by calling
// strip.Color(red, green, blue) as shown in the loop() function above),
// and a delay time (in milliseconds) between pixels.
void colorWipe(uint32_t color, int wait) {
for(int i=0; i<strip.numPixels(); i++) { // For each pixel in strip...
strip.setPixelColor(i, color); // Set pixel's color (in RAM)
strip.show(); // Update strip to match
delay(wait); // Pause for a moment
}
}

// Theater-marquee-style chasing lights. Pass in a color (32-bit value,
// a la strip.Color(r,g,b) as mentioned above), and a delay time (in ms)
// between frames.
void theaterChase(uint32_t color, int wait) {
for(int a=0; a<10; a++) { // Repeat 10 times...
for(int b=0; b<3; b++) { // 'b' counts from 0 to 2...
strip.clear(); // Set all pixels in RAM to 0 (off)
// 'c' counts up from 'b' to end of strip in steps of 3...
for(int c=b; c<strip.numPixels(); c += 3) {
strip.setPixelColor(c, color); // Set pixel 'c' to value 'color'
}
strip.show(); // Update strip with new contents
delay(wait); // Pause for a moment
}
}
}

// Rainbow cycle along whole strip. Pass delay time (in ms) between frames.
void rainbow(int wait) {
// Hue of first pixel runs 5 complete loops through the color wheel.
// Color wheel has a range of 65536 but it's OK if we roll over, so
// just count from 0 to 5*65536. Adding 256 to firstPixelHue each time
// means we'll make 5*65536/256 = 1280 passes through this loop:
for(long firstPixelHue = 0; firstPixelHue < 5*65536; firstPixelHue += 256) {
// strip.rainbow() can take a single argument (first pixel hue) or
// optionally a few extras: number of rainbow repetitions (default 1),
// saturation and value (brightness) (both 0-255, similar to the
// ColorHSV() function, default 255), and a true/false flag for whether
// to apply gamma correction to provide 'truer' colors (default true).
strip.rainbow(firstPixelHue);
// Above line is equivalent to:
// strip.rainbow(firstPixelHue, 1, 255, 255, true);
strip.show(); // Update strip with new contents
delay(wait); // Pause for a moment
}
}

// Rainbow-enhanced theater marquee. Pass delay time (in ms) between frames.
void theaterChaseRainbow(int wait) {
int firstPixelHue = 0; // First pixel starts at red (hue 0)
for(int a=0; a<30; a++) { // Repeat 30 times...
for(int b=0; b<3; b++) { // 'b' counts from 0 to 2...
strip.clear(); // Set all pixels in RAM to 0 (off)
// 'c' counts up from 'b' to end of strip in increments of 3...
for(int c=b; c<strip.numPixels(); c += 3) {
// hue of pixel 'c' is offset by an amount to make one full
// revolution of the color wheel (range 65536) along the length
// of the strip (strip.numPixels() steps):
int hue = firstPixelHue + c * 65536L / strip.numPixels();
uint32_t color = strip.gamma32(strip.ColorHSV(hue)); // hue -> RGB
strip.setPixelColor(c, color); // Set pixel 'c' to value 'color'
}
strip.show(); // Update strip with new contents
delay(wait); // Pause for a moment
firstPixelHue += 65536 / 90; // One cycle of color wheel over 90 frames
}
}
}

Kontakt os

Du er altid velkommen til at kontakte os på info@ardustore.dk, eller vores kontaktformular HER.