DFPlayer Mini MP3 Player Module

Installere Arduino IDE Software

Før du kan starte din programmering skal Arduino’s IDE software hentes. Dette program bruges til at programmere din arduino.
Download fra dette link: Download

Programmering

Inden programmeringen kan udføres skal de rigtige “Optiens” findes. Åben linket til den udviklingsboard du bruger.

Eksempel

Her viser vi et hurtig eksempel på hvordan du kan afspille 2 MP3 filer med Pause / Stop / Tilbage / Frem.

Du skal bruge:

• Arduino Uno R3 (Udviklingsboard)
• Mini-B USB stik
• Minihøjttaler DIY 1000Hz 800mW Ø30 – 8 Ohm
• Micro SD TF Flash Memory Card 128MB
• Memory Card Micro USB Adapter
• Dupont Breadboard Kabel
• KY-004 Tryk Knap Module
• 1K Ohm’s Modstand

Download 2x test filer her:

Disse 2 lyd MP3 filer skal bare ligges direkte på dit SD kort.

• Download Test MP3 fil 1
• Download Test MP3 fil 2

Forbind Modulet sådan:

Husk 1K modstand som tager støjen på serial forbindelsen.

• Arduino Pin 2 = Næste sang
• Arduino Pin 3 = Stop/Start
• Arduino Pin 4 = Sang tilbage

#include "SoftwareSerial.h"
SoftwareSerial mySerial(10, 11);
# define Start_Byte 0x7E
# define Version_Byte 0xFF
# define Command_Length 0x06
# define End_Byte 0xEF
# define Acknowledge 0x00 //Returns info with command 0x41 [0x01: info, 0x00: no info]
# define ACTIVATED LOW
int buttonNext = 2;
int buttonPause = 3;
int buttonPrevious = 4;
boolean isPlaying = false;
void setup () {
pinMode(buttonPause, INPUT);
digitalWrite(buttonPause,HIGH);
pinMode(buttonNext, INPUT);
digitalWrite(buttonNext,HIGH);
pinMode(buttonPrevious, INPUT);
digitalWrite(buttonPrevious,HIGH);
mySerial.begin (9600);
delay(1000);
playFirst();
isPlaying = true;
}
void loop () {
if (digitalRead(buttonPause) == ACTIVATED)
{
if(isPlaying)
{
pause();
isPlaying = false;
}else
{
isPlaying = true;
play();
}
}
if (digitalRead(buttonNext) == ACTIVATED)
{
if(isPlaying)
{
playNext();
}
}
if (digitalRead(buttonPrevious) == ACTIVATED)
{
if(isPlaying)
{
playPrevious();
}
}
}
void playFirst()
{
execute_CMD(0x3F, 0, 0);
delay(500);
setVolume(20);
delay(500);
execute_CMD(0x11,0,1);
delay(500);
}
void pause()
{
execute_CMD(0x0E,0,0);
delay(500);
}
void play()
{
execute_CMD(0x0D,0,1);
delay(500);
}
void playNext()
{
execute_CMD(0x01,0,1);
delay(500);
}
void playPrevious()
{
execute_CMD(0x02,0,1);
delay(500);
}
void setVolume(int volume)
{
execute_CMD(0x06, 0, volume); // Set the volume (0x00~0x30)
delay(2000);
}
void execute_CMD(byte CMD, byte Par1, byte Par2)
// Excecute the command and parameters
{
// Calculate the checksum (2 bytes)
word checksum = -(Version_Byte + Command_Length + CMD + Acknowledge + Par1 + Par2);
// Build the command line
byte Command_line[10] = { Start_Byte, Version_Byte, Command_Length, CMD, Acknowledge,
Par1, Par2, highByte(checksum), lowByte(checksum), End_Byte};
//Send the command line to the module
for (byte k=0; k<10; k++)
{
mySerial.write( Command_line[k]);
}
}